Windows批量取消文件只读属性-集成右键菜单版

垃圾微信，发送接收什么文件，即便一模一样都要重复存一遍，还自动给你搞个只读。老白写这个Windows小脚本功能即为：键移除当前目录（含所有子文件夹）内文件/文件夹的只读属性。运行后自动处理全部内容，完成后提示成功信息，3秒后自动关闭窗口，无需手动操作。

1.添加脚本

①右键，选择新建，用记事本新建文件

②粘贴下面的代码

说明

建议安装后重启一遍电脑

（或者直接下载bat脚本安装：https://qtrj.lanzoul.com/i0hpd2ovoi7c）

@echo off
setlocal enabledelayedexpansion

:: 执行模式判断
if "%~1"=="/process" (
    attrib -R *.* /S /D
    echo 所有文件和文件夹的只读属性已成功移除！
    echo 窗口将在3秒后自动关闭...
    ping 127.0.0.1 -n 3 > nul
    exit
)

:: 管理员权限检查
net session >nul 2>&1
if %errorLevel% neq 0 (
    echo 正在请求管理员权限...
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    echo UAC.ShellExecute "cmd.exe", "/c ""%~f0""", "", "runas", 1 >> "%temp%\getadmin.vbs"
    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs" >nul 2>&1
    exit /b
)

:: 确保脚本目录存在
if not exist "C:\Scripts\" (
    mkdir "C:\Scripts" >nul 2>&1
    if errorlevel 1 (
        echo 无法创建 C:\Scripts 目录
        pause
        exit
    )
)

:: 自我复制到指定路径
copy /y "%~f0" "C:\Scripts\RemoveReadOnly.bat" >nul
if errorlevel 1 (
    echo 文件复制到 C:\Scripts 失败
    pause
    exit
)

:: 注册表操作
reg add "HKEY_CLASSES_ROOT\Directory\Background\shell\RemoveReadOnly" /ve /d "移除只读属性" /f
reg add "HKEY_CLASSES_ROOT\Directory\Background\shell\RemoveReadOnly" /v "Icon" /d "imageres.dll,-5302" /f
reg add "HKEY_CLASSES_ROOT\Directory\Background\shell\RemoveReadOnly\command" /ve /d "\"C:\Scripts\RemoveReadOnly.bat\" /process" /f

:: 刷新资源管理器
taskkill /f /im explorer.exe >nul
start explorer.exe

echo 安装完成！
echo 右键菜单已添加至：C:\Scripts\RemoveReadOnly.bat
echo 注意：请勿移动或删除该路径下的脚本文件
pause

③另存为 RemoveReadOnly.bat，编码选择 ANSI，路径选择

2.使用方法

任意目录，右键菜单栏，选择“移除只读属性”

然后就会弹出窗口，如果觉得3秒关闭时间太长，可以在第一步的bat脚本中修改n 3 > nul

注意

常见office文件无需使用该脚本，直接打开微信，设置——文件管理，取消只读即可

3.卸载脚本

新建一个文本文件，将下方代码粘贴进去，然后改名bat运行，运行后重启电脑

@echo off
setlocal enabledelayedexpansion

:: 提权部分
net session >nul 2>&1
if %errorLevel% neq 0 (
    echo 请求管理员权限...
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    echo UAC.ShellExecute "cmd.exe", "/c ""%~f0""", "", "runas", 1 >> "%temp%\getadmin.vbs"
    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs" >nul 2>&1
    exit /b
)

:: 删除注册表项
reg delete "HKEY_CLASSES_ROOT\Directory\Background\shell\RemoveReadOnly" /f 2>nul
echo 已清理右键菜单项。

:: 删除脚本文件
del /f /q "C:\Scripts\RemoveReadOnly.bat" 2>nul

:: 删除空目录
rd "C:\Scripts" 2>nul && echo 已删除脚本目录。 || echo 目录非空，未删除。

:: 刷新资源管理器
taskkill /f /im explorer.exe >nul
start explorer.exe
echo 资源管理器已重启。

echo 卸载完成！
pause

更多实用Windows软件以及小技巧见文末标签！

Windows电脑和安卓手机查看已连接WiFi的密码